Skip to main content

Introduction To Replacement Shaders & Shader Keywords


What is a replacement shader?

A replacement shader is a shader that gets applied to every object being rendered.
Since the camera determines what objects end up being shown on screen, The functionality for setting up replacement shaders are in the camera class as well.

A good use case of a replacement shader would be in making effects like SSAO.
Here we need access to the normals and the depth information so a replacement shader that displays only the normals can be rendered ( stored in a render texture ) and then another shader that displays the depth information ( stored in a render texture ) and then the final image is rendered with the SSAO effect by taking the two render textures as input and doing a bunch of calculations.

Another use case would be to visualize the environment differently for various reasons like how they did in City Skylines.
City skylines replacement shader

The function that performs shader replacement is:
Camera.SetReplacementShader( Shader shader, string replacementTag )
  • Takes in a shader as parameter which will be the shader applied for replacing.
  • The replacementTag is sort of like a filter that applies the replacement only on objects which have a sub-shader that has a similar tag.
  • If you keep the replacementTag as "" (empty) then the shader will be applied to all the objects in the scene. 
So that now we have an understanding of what a replacement shader does we now have to look at what shader keywords are.

What is a shader keyword?

A shader keyword is used to enable or disable certain preprocessor directives and thereby have multiple shader variants be generated.
Each shader variant is basically a different shader except it shares the same properties and all the variations are defined in one shader file.

Let's look at some code on to create, enable and disable shader keywords.
First a sample shader.
Shader "BitshiftProgrammer/ExampleReplacement"
{
   SubShader
   {
 Tags { "RenderType"="Opaque" }
 Pass
 {
  CGPROGRAM
  #pragma vertex vert
  #pragma fragment frag
  #pragma shader_feature YELLOW_COL // Shader keyword
  #pragma shader_feature RED_COL // Shader keyword
  #include "UnityCG.cginc"

  struct appdata
  {
   float4 vertex : POSITION;
  };

  struct v2f
  {
   float4 vertex : SV_POSITION;
  };
   
  v2f vert (appdata v)
  {
   v2f o;
   o.vertex = UnityObjectToClipPos(v.vertex);
   return o;
  }
   
  fixed4 frag (v2f i) : SV_Target
  {
   #if RED_COL
   return fixed4(1,0,0,1); // Red if keyword enabled
   #endif
   #if YELLOW_COL
   return fixed4(1,1,0,1); // Yellow if keyword enabled
   #endif
   return fixed4(1,1,1,1); // White if no keyword enabled
  }
  ENDCG
 }
   }
}
Shader keywords work just like conditional complation pre-processor directives.
We have to explicitly say #pragma shader_feature SHADER_KEYWORD other wise it won't work in that sub-shader.
If you are not familiar with pre-processor directives in C#, I would suggest this : C# Fundamentals Pre-Processor Directives
The functions that are involved with shader replacement are:
Shader.EnableKeyword(string keyword)
Global state set to 'enabled' for that keyword and any shader that uses that keyword will be affected.
Shader.DisableKeyword(string keyword)
Global state set to 'disabled' for that keyword and any shader that uses that keyword will be affected.
  • So inorder to output red color you would write: Shader.EnableKeyword("RED_COL");
  • Then to show yellow you would write Shader.EnableKeyWord("YELLOW_COL");
    But you will still see red because the YELLOW_COL keyword was not disabled.
  • So for that, we have to write Shader.DisableKeyword("RED_COL");

Example of replacement shaders and shader keywords in action

Replacement shaders are a really good debugging tool as well.
Here is an example of what I mean.
Example 1 : Render all objects in various ways. ( Using shader keywords to get different outputs )
Here we are seeing:
Unlit shading, UVs, Local position, World position, Depth, Local-space normal, World-space normal

Example 2 : Render only objects that have a sub-shader with a specific replacement tag.
( Using shader keywords to get different outputs )
As you can see the ground  and the cubes are not rendered as the tag was only found on the trees and house.
Now we will actually implement this with the help of 2 shaders and 1 C# script.
We need 2 shaders :
1)The shader that actually gets replaced when replacing with tag
2)The shader that will be put in it's place

So now we will look at the shader which will be used to render by default but then get replaced.
"BitshiftProgrammer/ShaderToBeReplacedWithTag"
{
 Properties 
 {
  _MainTex ("Base (RGB)", 2D) = "white" {}
 }

 SubShader 
 {
  Cull off
  Tags { "RenderType"="Opaque" "MyTag"="OnlyColors" } // Tagged with "MyTag"

  CGPROGRAM
  #pragma surface surf Lambert noforwardadd

  sampler2D _MainTex;
  struct Input
  {
   float2 uv_MainTex;
  };

  void surf (Input IN, inout SurfaceOutput o)
  {
   fixed4 c = tex2D(_MainTex, IN.uv_MainTex);
   o.Albedo = c.rgb;
   o.Alpha = c.a;
  }
  ENDCG
 }
 Fallback "Mobile/VertexLit"
}
So as you can see it's a simple lit surface shader but with an extra tag called "MyTag".
Now the shader that will replace that one.
Shader "BitshiftProgrammer/Replacer"
{
   Properties
   {
 _MainTex ("Texture", 2D) = "white" {}
   }

   SubShader
   {
 Tags { "RenderType"="Opaque" }

 Pass
 {
  CGPROGRAM
  #pragma vertex vert
  #pragma fragment frag
  #pragma shader_feature UV_VIS
  #pragma shader_feature LOCAL_POS_VIS
  #pragma shader_feature WORLD_POS_VIS
  #pragma shader_feature DEPTH_VIS
  #pragma shader_feature LOCAL_NORMAL_VIS
  #pragma shader_feature WORLD_NORMAL_VIS
  #include "UnityCG.cginc"

  struct appdata
  {
   float4 vertex : POSITION;
   float2 uv : TEXCOORD0;
   float3 normal : NORMAL;
  };

  struct v2f
  {
   float2 uv : TEXCOORD0;
   float3 worldPos : TEXCOORD1;
   float3 localPos : TEXCOORD2;
   float  depth : TEXCOORD3;
   float3 normal : TEXCOORD4;
   float4 vertex : SV_POSITION;
  };

  sampler2D _MainTex;
  float4 _MainTex_ST;
   
  v2f vert (appdata v)
  {
   v2f o;
   o.localPos = v.vertex;
   o.vertex = UnityObjectToClipPos(v.vertex);
   o.worldPos = mul(unity_ObjectToWorld, v.vertex);
   o.worldPos = normalize(o.worldPos);
   o.depth = -mul(UNITY_MATRIX_MV, v.vertex).z * _ProjectionParams.w;
   o.uv = v.uv;
   o.normal = v.normal;
   #if WORLD_NORMAL_VIS
   o.normal = mul(unity_ObjectToWorld, o.normal);
   #endif
   return o;
  }
   
  fixed4 frag (v2f i) : SV_Target
  {
   #if UV_VIS
   return fixed4(i.uv, 0, 1);
   #endif
   #if LOCAL_POS_VIS
   return fixed4(i.localPos, 1.0);
   #endif
   #if WORLD_POS_VIS
   return fixed4(i.worldPos, 1.0);
   #endif
   #if DEPTH_VIS
   return i.depth;
   #endif
   #if LOCAL_NORMAL_VIS || WORLD_NORMAL_VIS
   return fixed4(normalize(i.normal) * 0.5 + 0.5,1.0);
   #endif
   return tex2D(_MainTex, i.uv); //If no shader feature is enabled
  }
  ENDCG
 }
   }
   SubShader
   {
 Tags { "RenderType"="Opaque" "MyTag"="OnlyColors" } //Subshader with same tag "MyTag"

 Pass
 {
  CGPROGRAM
  #pragma vertex vert
  #pragma fragment frag
  #pragma shader_feature UV_VIS
  #pragma shader_feature LOCAL_POS_VIS
  #pragma shader_feature WORLD_POS_VIS
  #pragma shader_feature DEPTH_VIS
  #pragma shader_feature LOCAL_NORMAL_VIS
  #pragma shader_feature WORLD_NORMAL_VIS
  #include "UnityCG.cginc"

  struct appdata
  {
   float4 vertex : POSITION;
  };

  struct v2f
  {
   float4 vertex : SV_POSITION;
  };

  v2f vert (appdata v)
  {
   v2f o;
   o.vertex = UnityObjectToClipPos(v.vertex);
   return o;
  }

  fixed4 frag () : SV_Target
  {
   #if UV_VIS
   return fixed4(1,0,0,1);
   #endif
   #if LOCAL_POS_VIS
   return fixed4(0,1,0,1);
   #endif
   #if WORLD_POS_VIS
   return fixed4(0,0,1,1);
   #endif
   #if DEPTH_VIS
   return fixed4(1,1,0,1);
   #endif
   #if LOCAL_NORMAL_VIS
   return fixed4(1,0,1,1);
   #endif
   #if WORLD_NORMAL_VIS
   return fixed4(0,1,1,1);
   #endif
   return fixed4(1,1,1,1);
  }
  ENDCG
 }
   }
}
You can see the same shader keywords have been used in both subshaders but different outputs have been described so that we know what is happening.
Now the C# script that will allow us control how everything is being rendered.
By looking at the C# script you will be able to understand exactly what is happening.

using UnityEngine;
public class ReplacementShaderTest : MonoBehaviour
{
    public Shader replaceShader;
    private string[] KeyWords = new string[] { "UV_VIS", "LOCAL_POS_VIS", "WORLD_POS_VIS", "DEPTH_VIS", "LOCAL_NORMAL_VIS", "WORLD_NORMAL_VIS" };

    private void Update()
    {
        if (Input.GetKeyDown(KeyCode.A))
            GetComponent().SetReplacementShader(replaceShader, ""); // All objects will have shader applied on it
        else if (Input.GetKeyDown(KeyCode.W))
            GetComponent().SetReplacementShader(replaceShader, "MyTag"); // Only objects which have shaders that have a sub-shader that has a tag called "MyTag" will be rendered
        else if (Input.GetKeyDown(KeyCode.S))
            GetComponent().ResetReplacementShader(); // Removes all applied replacement shaders
        else if (Input.GetKeyDown(KeyCode.Z))
            EnableKeyWord(0);
        else if (Input.GetKeyDown(KeyCode.Alpha1))
            EnableKeyWord(1);
        else if (Input.GetKeyDown(KeyCode.Alpha2))
            EnableKeyWord(2);
        else if (Input.GetKeyDown(KeyCode.Alpha3))
            EnableKeyWord(3);
        else if (Input.GetKeyDown(KeyCode.Alpha4))
            EnableKeyWord(4);
        else if (Input.GetKeyDown(KeyCode.Alpha5))
            EnableKeyWord(5);
        else if (Input.anyKeyDown)
            EnableKeyWord(-1); // Goto default functionality of sub-shader ( by disbaling all shader keywords )
    }

    private void EnableKeyWord(int index) // Only one shader keyword will be enabled at a time
    {
        for (int i = 0; i < KeyWords.Length; i++)
        {
            if (i == index)
                Shader.EnableKeyword(KeyWords[i]);
            else
                Shader.DisableKeyword(KeyWords[i]);
        }
    }
}
For the Unity package go: HERE
That's it! Hope you learned something. Support Bitshift Programmer by leaving a like on
Bitshift Programmer Facebook Page and be updated as soon as there is a new blog post.
If you have any questions that you might have about shaders or Unity development, in general, don't be shy and leave a message on my facebook page or down in the comments.
For the source code, go: HERE
For more Shader development tutorials, go: HERE
For Unity development tutorials, go: HERE
 

Comments

Post a Comment

Assets Worth Checking Out

POPULAR POSTS

How To Animate A Fish Swimming With Shaders

Animate Fish Swimming With Shaders We are going to make swimming animation by using only shader code.
By the time we are done, it's going to look like this.
You will probably need the fish model used in this tutorial, that can be found HERE. Can use your own model but the shader code might have to be modified accordingly because of the orientation of the model that you might be using ( issues with whether the X axis & Z axis is flipped ).
The shader used way out performs a similar scene with skeletal animations applied on the fish models.
On a previous benchmark I did comparing the shader animation with the skeletal animation there was a difference of 28 FPS( on average ) with 50 fish.
The shader we are going to make is really powerful and flexible and don't think that it's limited to making fishes swim😀.


So this mesh oriented like this when imported into unity and this is important to understand because this means that the model's vertices have to be moved along the X-…

Pixelation Shader - Unity Shader

Pixelation Shader This is the correct way (one of many) of showing pixelation as a post-processing effect. This effect will work in any aspect ratio without any pixel size scaling issues as well as it is very minimal in terms of coding it up.

In order to get this to work 2 components have to be set up:
1) The pixelation image effect
2) The script - which will be attached to the camera

So let's get started by creating a new image effect shader.
We will take a look at our Shaderlab properties :
_MainTex("Texture", 2D) = "white" {} That's it, Everything else will be private and not shown in the editor.
Now we will see what are defined along with the _MainTex but are private.
sampler2D _MainTex; int _PixelDensity; float2 _AspectRatioMultiplier; We will pass _PixelDensity & _AspectRatioMultiplier values from the script.
As this is an image effect there is no need to play around with the vertex shader.
Let's take a look at our fragment shader:
fixed4 frag (…

Curved Surface Shader [ Unity Implementation ]

Curved Surface Shader This is the shader that we will be having at the end of this tutorial.
 The curved surface shader is capable of achieving really varied visual effects from showing space-time curve due to gravity to a generic curved world shader that is seen in endless runners like Subway Surfers.
The concepts that you learn here can open you up to a new way of looking at shaders and if you didn't think they were the coolest thing ever already, hopefully let this be the turning point.😝.

Both the examples show above use the same exact material is just that different values have been passed to the shader.
Start by creating a new unlit shader in Unity and we will work our way from there.
First we define what the properties are:
_MainTex("Texture", 2D) = "white" {} _BendAmount("Bend Amount", Vector) = (1,1,1,1) _BendOrigin("Bend Origin", Vector) = (0,0,0,0) _BendFallOff("Bend Falloff", float) = 1.0 _BendFallOffStr("Falloff s…

Toon Liquid Shader - Unity Shader

Toon Liquid Shader This is how the shader will end up looking :
This shader is pretty neat and somewhat easy to implement as well as to understand. Since we will be adding some basic physics to the toon water as it is moved about we will have to support that in the vertex shader as well.
So let's start by looking at the properties :
Properties { _Colour ("Colour", Color) = (1,1,1,1) _FillAmount ("Fill Amount", Range(-10,10)) = 0.0 [HideInInspector] _WobbleX ("WobbleX", Range(-1,1)) = 0.0 [HideInInspector] _WobbleZ ("WobbleZ", Range(-1,1)) = 0.0 _TopColor ("Top Color", Color) = (1,1,1,1) _FoamColor ("Foam Line Color", Color) = (1,1,1,1) _Rim ("Foam Line Width", Range(0,0.1)) = 0.0 _RimColor ("Rim Color", Color) = (1,1,1,1) _RimPower ("Rim Power", Range(0,10)) = 0.0 } Just the usual stuff that we are used to. The only thing that may stand out is the [HideInInspector] tag, This works j…

Access Reflection Probe Data For Custom Shaders

The Unity shader documentation regarding reflection probes is pretty minimal and not at all comprehensive.
This short tutorial is intended to bring reflection probe functionalities to the forefront your future shader writing endevors which is a fancy way of saying "Look at this cool stuff and go and use it somewhere" 😏
Here we will try just the bare minimum of making a shader that reflects the cubemap data from reflection probe and displays it on the object.

These reflection probes are basically objects that store a complete image of the environment surrounding it into a cubemap which then can be read by shaders to create various effects.
More information on how reflection probes work in Unity can be found here :
Using Reflection Probes In Unity

I am not going over how to set up Reflection Probes here only how to access them inside our custom shaders.
So this is what we will be making:
The reflection probe takes in the cubemap only if it is within it's range otherwise i…