Skip to main content

Fortnite Procedural Construction Animation Shader


Fortnite Construction Shader

This shader is loosely based on the one that was presented by the Fortnite developers in their GDC talk: Inner Working Of Fortnite's Shader-Based Procedural Animations.

 Here is what we will end up with:
Fortnite building shader
This technique requires you to author the 3D model in a certain way, More or less how those Fortnite developers did.
So we need the authored 3D model and the shader that uses data we get from the model to achieve the desired effect.

There are some nuances here and there so make sure you don't miss out on the details.😗
The first step will be preparing the 3D model and putting in the required data. I used Blender 2.79 but any 3D modeling software would do.

3D Model Preparation

  1. Model It
    3d mesh
  2. Apply Vertex Colors: For the direction of flight
    Each color is a component of a vector (x, y, z). This will be considered as local space.
    Values range from -1.0 to +1.0 for each component.
    Negative values are achieved by using values of less than 0.5 and positive values with values greater than 0.5.
    Assume 'val' : Range from 0.0 - 1.0
    You can use your own mapping such as '(val - 0.5) * 2'.
    • Gives -1.0 if val was 0.0
    • Gives +1.0 if val was 1.0
    • Gives 0.0 if val was 0.5
    • Gives 0.5 if val was 0.75
    • Gives -0.5 if val was 0.25
    Basically :
    (0.0 , 0.5) maps to (-1.0 , 0.0)
    (0.5 , 1.0) maps to (0.0 , 1.0)
    The mapping I've used :
    • Gives 0.0 if val was 0.5
    • Gives +1.0 if val was 1.0
    • Gives 0.0 if val was 0.0
    • Gives 0.5 if val was 0.75
    • Gives -0.5 if val was 0.25
    • Gives -1.0 if val was 0.4999 (less than 0.5 but tending towards it)
    Basically :
    (0.0 , 0.5) maps to (0.0 , -1.0)
    (0.5 , 1.0) maps to (0.0 , 1.0)
    vertex colors
  3. UV Channel 1: For applying timing textures and rotation amount.
    The UV map is difficult to see, I suggest zooming in. Those dots placed are each of the separate vertex sections that make up the mesh.
    Shown here : Red channel = x position of UV & Green channel = y position of UV
    • The greater the UV's x coordinate of a vertex the later movement of the vertices will start ( assuming the initial stage was having all pieces together )
    • The greater the UV's y co-ordinate the more rotations about the local z-axis it will do.
    First UV Channel data for mesh
  4. UV Channel 2: Actual texture map.
    The texture used can be found here: Pexels - Antique Backdrop
    textured mesh

Fortnite Construction Surface Shader

We will be using a surface shader as our base. So go ahead and create one.
  1. Defining Our Properties
    Properties 
    {
     _Color ("Color", Color) = (1,1,1,1)
     [HideInInspector]_MainTex("Main texture", 2D) = "white"{}
     _ActualTex("Actual Texture", 2D) = "white"{}
     _Glossiness ("Smoothness", Range(0,1)) = 0.5
     _Metallic ("Metallic", Range(0,1)) = 0.0
     _Placement("Placement value", Range(-0.0, 100.0)) = 0.0
    }
    
    We don't actually end up using _MainTex in our shader, But we need to declare it here due to quirks of using a secondary UV channel.
    Since we don't end up using it we can hide it in the inspector with [HideInInspector] attribute.
  2. Input Struct & CG Declarations
    sampler2D _ActualTex;
    sampler2D _MainTex;
    half _Glossiness;
    half _Metallic;
    fixed4 _Color;
    float _Placement;
    
    struct Input 
    {
     float2 uv_MainTex; // UV co-ordinates for our timing & rotation about z-axis
     float2 uv2_ActualTex; // 2nd UV co-ordinate used for the actual texturing purposes
     float4 color : COLOR; // Vertex color
    };
    
  3. Helper Functions
    float3 ConvertToDir(float3 val)
    {
     val.x = lerp(-val.x * 2, (val.x - 0.5) * 2, step(0.5, val.x));
     val.y = lerp(-val.y * 2, (val.y - 0.5) * 2, step(0.5, val.y));
     val.z = lerp(-val.z * 2, (val.z - 0.5) * 2, step(0.5, val.z));
     //In case it's not clear, With a conditional statement : val.z = (val.z < 0.5)? -val.z * 0.5 : (val.z -0.5) * 2;
     //Alternative mapping : val.z = (val.z - 0.5) * 0.5;
     val = normalize(val);
     return val;
    }
    
    float4 RotateAroundZInDegrees (float4 vertex, float degrees)
    {
            //Creating a rotation matrix to multiply with our vertex position
     float angle = radians(degrees);
     float c = cos(angle);
     float s = sin(angle);
     float4x4 rotateZMatrix = float4x4(c,-s,0,0,
            s,c,0,0,
            0,0,1,0,
            0,0,0,1);
     return mul(vertex , rotateZMatrix);
    }
    
  4. The Vertex Shader
    void vert (inout appdata_full v) 
    {
     /*1*/float val = max((_Placement - v.texcoord.x * 100), 0);
     /*2*/v.vertex = RotateAroundZInDegrees(v.vertex, val * v.texcoord.y * 100);
     /*3*/v.vertex.xyz += ConvertToDir(v.color.xyz) * val;
    }
    
    *Note: The _Placement value is the value that determines where our vertices end up.
    v.texcoord.x:- Timing value, Determines when the movement of the vertices for that vertex starts. (Range : 0.0 - 1.0)
    v.texcoord.y:- The amount of rotation to be applied. (Range : 0.0 - 1.0)
    1. When _Placement value crosses the threshold value set by (v.texcoord.x * 100) only then the vertex moves.
    2. The lower the value of 'val' less the rotation applied on the vertex.
    3. The 'ConvertToDir(v.color.xyz)' function takes in vertex color and converts that into a direction for the vertex to move. Then we multiply with 'val' thereby determining the distance the vertex moves in that direction.
  5. The Surface Shader
    void surf (Input IN, inout SurfaceOutputStandard o) 
    {
     fixed4 c = tex2D (_ActualTex, IN.uv2_ActualTex) * _Color;
     o.Albedo = c.rgb;
     o.Metallic = _Metallic;
     o.Smoothness = _Glossiness;
     o.Alpha = c.a;
    }
    
    Nothing mystical happening here. Sampling our texture with the correct texture map and UV coordinates.
  6. Vertex Shader Declaration And Shadow Pass
    #pragma surface surf Standard fullforwardshadows vertex:vert addshadow
    We need to declare our vertex function with 'vertex:vert' since our vertex function is called 'vert'.
    We are modifying our vertices so the shadows won't look correct as it's using Unity's default shadow pass, So we need to tell Unity to use a custom shadow pass which takes into consideration those new vertex positions; To do this 'addshadow' is used in our #pragma.
That's it! Hope you learned something.
Support Bitshift Programmer by leaving a like on Bitshift Programmer Facebook Page and be updated as soon as there is a new blog post.
If you have any questions that you might have about shaders or unity development in general, don't be shy and leave a message on my facebook page or down in the comments.
For the Unity-Package, go HERE.
For the entire source code, go HERE.
For more Shader development tutorials, go: HERE
For Unity development tutorials, go: HERE

Assets Worth Checking Out

POPULAR POSTS

Introduction To Replacement Shaders & Shader Keywords

What is a replacement shader? A replacement shader is a shader that gets applied to every object being rendered.
Since the camera determines what objects end up being shown on screen, The functionality for setting up replacement shaders are in the camera class as well.

A good use case of a replacement shader would be in making effects like SSAO.
Here we need access to the normals and the depth information so a replacement shader that displays only the normals can be rendered ( stored in a render texture ) and then another shader that displays the depth information ( stored in a render texture ) and then the final image is rendered with the SSAO effect by taking the two render textures as input and doing a bunch of calculations.

Another use case would be to visualize the environment differently for various reasons like how they did in City Skylines.

The function that performs shader replacement is:
Camera.SetReplacementShader( Shader shader, string replacementTag ) Takes in a shader as …

Curved Surface Shader [ Unity Implementation ]

Curved Surface Shader This is the shader that we will be having at the end of this tutorial.
 The curved surface shader is capable of achieving really varied visual effects from showing space-time curve due to gravity to a generic curved world shader that is seen in endless runners like Subway Surfers.
The concepts that you learn here can open you up to a new way of looking at shaders and if you didn't think they were the coolest thing ever already, hopefully let this be the turning point.😝.

Both the examples show above use the same exact material is just that different values have been passed to the shader.
Start by creating a new unlit shader in Unity and we will work our way from there.
First we define what the properties are:
_MainTex("Texture", 2D) = "white" {} _BendAmount("Bend Amount", Vector) = (1,1,1,1) _BendOrigin("Bend Origin", Vector) = (0,0,0,0) _BendFallOff("Bend Falloff", float) = 1.0 _BendFallOffStr("Falloff s…

Noise Generation Algorithms : White Noise With Shader Example

White Noise Many of you may know what white noise is and how it can be used in code.
But there are a spectrum of  'Coloured Noises' as well these include ones like brown noise, pink, blue and violet noise all these have slightly different properties and can be very useful in creating different effects. More details on coloured noises can be found HERE.
A lot of movies as well as video games like City Skylines use white noise to add a feeling of realism and texture to the on screen content, it's also referred to as a grain filter or overlay. It is a really subtle effect and should not be over used.
Creating white noise boils down to the random function used.
While writing C++ code or C# code we have access to good pseudo-random functions from their standard libraries... but while writing code in shaders we usually have to create our own pseudo-random number generator.
One really good way of making one is by using the frac( in Unity & HLSL ) or fract( in GLSL ) functio…

Alto's Adventure Style Procedural Surface Generation Part 1

Alto's Adventure Style - Procedural Surface Generation This game appears to be a strictly 2D game but if you have played it enough you will notice that some of the art assets used look like it's 3D ( I don't know if they are tho ). If you haven't played the game you are missing out on one the most visually pleasing and calming games out there ( There is literally a mode called Zen mode in the game ).
Anyway, I am going to show you how to make a procedural 2D world ( without the trees, buildings and background ) like in Alto's Adventure.
But you may notice I have a plane which is in in the Z-axis giving a depth to the surface which is not there in Alto's Adventure but if you want to know how to do it then that will be in part 2.
To achieve the same effect of Alto's Adventure ( I'm leaving that up to you ) only minimal changes are needed to the code that I am going to explain.
We are going to be using the plane mesh in unity for creating the 2D surface as th…

Making An Audio Visualizer In Unity With Blend Shapes & Audio API - Part 1

Audio Visualizer with Unity Audio API & Blend Shapes This tutorial is going to be split into two parts, The first part (this one) we are going to be covering Blendshapes, what they are, what it's used for and how to use them in Unity and in Part 2 we will cover integrating that with Unity's audio API to get the desired result.
So now you got a feel as to what we will be making.
Blendshapes are just like transitions that the vertices go through to go from being in one position in space to another with the help of a transition value. All the major 3d modelling software from Blender to Maya has it.
As you can see that the model has 2 shape keys, one called MinValue and another called MaxValue, these names don't carry over into unity but the index of the shape key( blend shape ) matters.
We will be manipulating the MaxValue to make changes to the mesh.
This is how the model looks when it has it's MaxValue set at zero.
You may have guessed now that it is just a basic linear i…